访问关系型数据库系统中的数据

访问关系型数据库系统中的数据

SAS提供了一组访问关系型数据库的SAS/ACCESS接口，每种接口有单独的许可。使用这些接口，SAS可以和其他厂商数据库中的数据交互。SAS所支持的关系型数据库如表2.3所示。

表2.3 SAS支持的关系型数据库

除了上述关系型数据库外，SAS还提供了对应的SAS/ACCESS引擎访问ERP、SPSS等系统软件中的数据。这些内容本书不做介绍，读者如果有需要可以参考SAS帮助文档学习。

SAS/ACCESS接口引擎提供以下方法访问关系型DBMS中的数据：

使用LIBNAME语句将SAS逻辑库引用名定义到DBMS对象，例如schema和数据库。

还可以使用ACCESS过程来访问数据库系统，但是SAS不推荐使用这种方式。SAS推荐使用更直接的方式访问DBMS数据，如上面提到的两种。所以，本文不介绍ACCESS过程，感兴趣的读者可以通过SAS帮助文档了解。

通过LIBNAME语句访问

在介绍SAS逻辑库的文章里，已经提到了接口逻辑库引擎的概念。接口逻辑库是通过SAS/ACCESS接口软件来访问的其他软件，例如数据库管理系统、格式化的文件等。通过LIBNAME语句指定接口逻辑库的引用名后，就可以像访问SAS原生数据集一样通过二级引用来访问数据库中的表了。这时数据库中的表也称为接口数据集。这里简单介绍SAS/ACCESS用LIBNAME语句访问关系型数据库的一般用法，更详细的用法请查看SAS帮助文档。

注意：

大多数情况下，接口数据集的使用与原生数据集没有区别，但仍然会有些限制。例如在DATA步的DATA语句和SET语句中不能指定同一个接口数据集，否则SAS会报错。

LIBNAME语句指定到DBMS对象的逻辑库引用名的基本形式如下：

LIBNAME 逻辑库引用名 逻辑库引擎 访问连接选项;

其中：

下面两条LIBNAME语句分解建立了到Teradata数据库和Oracle数据库的逻辑库引用名。接着，就可以使用带逻辑库引用名tdlib和oralib的二级名称引用数据库中的表了。

libname tdlib teradata server=tera2650 database=hps user=user1 password=password1;

libname oralib oracle path=mypath schema=myschema user=usr1 password=password1;

通过PROC SQL访问

PROC SQL为SAS软件实现了结构化查询语句（Structured Query Language，SQL）。关于PROC SQL的信息在后面的文章里会详细讲解。这里主要是介绍如何通过PROC SQL使用SAS/ACCESS访问关系型数据库：

前两种方法仍然使用的是SAS/ACCESS LIBNAME引擎，引用数据库中表的形式与引用SAS原生数据集相同，这里不做介绍。作为LIBNAME语句的替代，SQL转交功能使用SAS/ACCESS连接DBMS，并将语句直接放到DBMS执行，这样就可以使用DBMS本身的SQL语法了。所以，SQL转交功能支持当前DBMS支持的任何非ANSI标准的SQL。需要注意的是，不是所有的SAS/ACCESS接口都支持这种属性。

使用SQL转交功能的基本形式如下：

PROC SQL;

CONNECT TO 数据库名称 <AS 别名> <(<数据库连接参数> )>;

EXECUTE (数据库特定SQL语句) BY 数据库名称|别名;

SELECT 列列表FROM CONNECTION TO数据库名称|别名 (数据库查询);

DISCONNECT FROM数据库名称|别名;

QUIT；

在上述形式中：

各语句执行的返回值和消息保存在宏变量&sqlxrc和&sqlxmsg中。

下面的代码建立到Oracle数据库的连接，在CONNECT语句中，oracle为数据库名称、mycon为别名、括号里的内容为数据库的连接参数。%put宏将上一条CONNECT语句的返回值和代码打印到日志窗口。SELECT语句通过建立的连接将表employees中满足条件（hiredate>="31-DEC-88"）的行指定的5列（empid、 lastname、firstname、hiredate、salary）数据取出。

proc sql;

connect to oracle as mycon (user=myusr1

password=mypwd1 path="mysrv1" schema=myshm1);

%put &sqlxmsg;

select *

from connection to mycon

(select empid, lastname, firstname,

hiredate, salary

from employees where

hiredate>="31-DEC-88");

%put &sqlxmsg;

disconnect from mycon;

quit;

PROC SQL还可以将上面的查询存储为SQL视图或创建为SAS数据集。下面的代码中查询条件一样，还是将查询存储为SAS逻辑库中的SQL视图，这样在下次使用该视图时就可以自动从数据库中获取数据了。

libname samples "SAS-library";

proc sql;

connect to oracle as mycon (user=myusr1

password=mypwd1 path="mysrv1" schema="schm1");

%put &sqlxmsg;

create view samples.hires88 as

select *

from connection to mycon

(select empid, lastname, firstname,hiredate, salary

from employees where

hiredate>="31-DEC-88");

%put &sqlxmsg;

disconnect from mycon;

quit;

使用SQL转交（pass-through）功能。通过该功能，在SAS会话中可以使用原生SQL语法与数据源交互，这些SQL语句会直接交给数据源处理。

逻辑库引用名为访问数据库的逻辑引用名称，在介绍SAS逻辑库的文章里有详细介绍。

逻辑库引擎由所要访问的数据库确定，例如Oracle数据库引擎为oracle，Teradata数据库引擎为teradata，Hadoop的引擎为hadoop。

访问连接选项提供连接信息并控制SAS如何管理到DBMS链接的时机和并发。不同数据库，连接选项会不同。例如，连接到Oracle数据的连接选项为User=、PASSWORD=和PATH=。

使用LIBNAME语句指定接口逻辑库引用名，然后在PROC SQL语句中引用该引用名查询、更新或删除DBMS数据。

将LIBNAME信息嵌入到PROC SQL视图，在每次处理该SQL视图时自动连接到DBMS。

使用PROC SQL的扩展功能，将DBMS特定的SQL语句直接发送到DBMS，该功能叫做SQL转交（pass-through）功能。

CONNECT语句建立到DBMS的连接：数据库名称标识要连接的数据库管理系统；别名为该连接指定别名；数据库连接参数指定PROC SQL连接到DBMS需要的特定的DBMS参数。

EXECUTE语句发送DBMS特定的、非查询SQL语句到DBMS。SAS会把输入的内容原封不动地发送到DBMS。有些DBMS可能是大小写敏感的，需要注意。

CONNECTION TO组件获取并使用PROC SQL查询或视图中的DBMS数据。数据库查询指定要发送到DBMS上的查询，该查询可使用对该DBMS有效的任何DBMS特定的SQL语句或语法。同样，这些查询对有些DBMS可能是大小写敏感的。

DISCONNECT语句终止到DBMS的连接。